# Prometheus server with data volume and floating IP

# Data volume for Prometheus (SSD)
resource "openstack_blockstorage_volume_v3" "prometheus_data_vol" {
  name                 = local.prometheus_server_data.vol_data_name
  size                 = local.prometheus_server_data.vol_data_size
  volume_type          = "CephSSD"
  enable_online_resize = true
}

# Port in the main private network
resource "openstack_networking_port_v2" "prometheus_server_port" {
  name           = "${local.prometheus_server_data.name}-port"
  admin_state_up = true
  network_id     = local.main_private_network_id
  security_group_ids = [
    openstack_networking_secgroup_v2.default.id,
    openstack_networking_secgroup_v2.restricted_web.id,
    openstack_networking_secgroup_v2.prometheus_access_from_grafana.id
  ]
  fixed_ip {
    subnet_id  = local.main_private_subnet_id
    ip_address = local.basic_services_ip.prometheus
  }
}

# Prometheus server instance
resource "openstack_compute_instance_v2" "prometheus_server" {
  name                    = local.prometheus_server_data.name
  availability_zone_hints = local.availability_zones_names.availability_zone_no_gpu
  flavor_name             = local.prometheus_server_data.flavor
  key_pair                = module.ssh_settings.ssh_key_name

  block_device {
    uuid                  = local.ubuntu_2404.uuid
    source_type           = "image"
    volume_size           = 10
    boot_index            = 0
    destination_type      = "volume"
    delete_on_termination = false
  }

  network {
    port = openstack_networking_port_v2.prometheus_server_port.id
  }

  user_data = file("${local.ubuntu2404_data_file}")
  # Do not replace the instance when the ssh key changes
  lifecycle {
    ignore_changes = [
      key_pair, user_data, network
    ]
  }
}

# Attach data volume to Prometheus server
resource "openstack_compute_volume_attach_v2" "prometheus_data_attach_vol" {
  instance_id = openstack_compute_instance_v2.prometheus_server.id
  volume_id   = openstack_blockstorage_volume_v3.prometheus_data_vol.id
  device      = local.prometheus_server_data.vol_data_device
}

# Floating IP and DNS record
resource "openstack_networking_floatingip_v2" "prometheus_server_ip" {
  pool        = local.floating_ip_pools.main_public_ip_pool
  description = "Prometheus server"
}

resource "openstack_networking_floatingip_associate_v2" "prometheus_server" {
  floating_ip = openstack_networking_floatingip_v2.prometheus_server_ip.address
  port_id     = openstack_networking_port_v2.prometheus_server_port.id
}

locals {
  prometheus_recordset_name   = "${local.prometheus_server_data.name}.${local.dns_zone.name}"
  alertmanager_recordset_name = "alertmanager.${local.dns_zone.name}"
}

resource "openstack_dns_recordset_v2" "prometheus_server_recordset" {
  zone_id     = local.dns_zone_id
  name        = local.prometheus_recordset_name
  description = "Public IP address of the Prometheus server"
  ttl         = 8600
  type        = "A"
  records     = [openstack_networking_floatingip_v2.prometheus_server_ip.address]
}

resource "openstack_dns_recordset_v2" "alertmanager_server_recordset" {
  zone_id     = local.dns_zone_id
  name        = local.alertmanager_recordset_name
  description = "Prometheus alertmanager"
  ttl         = 8600
  type        = "CNAME"
  records     = [local.prometheus_recordset_name]
}